Main Page

From EH izendegi

Ongi etorri IZENDEGI Wikibase instantziara. Wikibase hau UEUko Euskara eta Digitalitatea Aditu Tituluko "Sareko edukiak aztertzeko tresnak" ikasgaiko ariketa kolektiboaren emaitzak jasotzeko erabiltzen dugu momentu honetan.

Ikasleek Gasteizko kale-izendegiko sarrerak lotu dizkiote Wikidatako entitatei, honela kale bakoitza izena ematen dion entitatea zehaztuz. Open Refine softwarea erabili dute, eta hamar CSV fitxategi ekoitzi. Emaitzak script baten bitartez igo egin dira Wikibase honetara.

Ikasgaiko emaitzak eguneratu egin dira 2025ko urtarrilaren 2an.

Gasteizko kale-izendegia

Kaleak

PREFIX izwb: <https://izendegi.wikibase.cloud/entity/>
PREFIX izdp: <https://izendegi.wikibase.cloud/prop/direct/>
select * where {
  ?kalea izdp:P3 izwb:Q3;
         izdp:P10 ?id;
         rdfs:label ?izena.
  filter(lang(?izena)="eu")
  } order by xsd:integer(?id)

Try it!

Gasteizko kaleei izena ematen dieten entitateak

Entitate guztiak, zerrendan

#Title: Zeinen izena darama? Gasteizko kaleei izena ematen dieten entitateak
PREFIX izwb: <https://izendegi.wikibase.cloud/entity/>
PREFIX izdp: <https://izendegi.wikibase.cloud/prop/direct/>
select distinct ?kalea ?kale_izena ?honen_izena_darama ?honen_izena_daramaLabel ?klaseak where {
  ?kalea izdp:P3 izwb:Q3;
         izdp:P6 ?wd;
         rdfs:label ?kale_izena. filter(lang(?kale_izena)="eu")
  bind(iri(concat(str(wd:),?wd)) as ?honen_izena_darama)
  SERVICE <https://query.wikidata.org/sparql> {
           select ?honen_izena_darama ?honen_izena_daramaLabel (group_concat(distinct ?klase;SEPARATOR=", ") as ?klaseak) 
           where { ?honen_izena_darama wdt:P31 [rdfs:label ?klase]. filter(lang(?klase)="eu") 
                   ?honen_izena_darama rdfs:label ?honen_izena_daramaLabel. filter(lang(?honen_izena_daramaLabel)="eu")}
           group by ?honen_izena_darama ?honen_izena_daramaLabel ?klaseak }
  
  } order by ?kale_izena

Try it!

Entitateen klaseak

#Title: Zeinen izena darama? Gasteizko kaleei izena ematen dieten entitateen klaseak
#defaultView:BubbleChart
PREFIX izwb: <https://izendegi.wikibase.cloud/entity/>
PREFIX izdp: <https://izendegi.wikibase.cloud/prop/direct/>
select distinct ?klase ?klaseLabel (count(?honen_izena_darama) as ?zenbat) where {
  ?kalea izdp:P3 izwb:Q3;
         izdp:P6 ?wd;
         rdfs:label ?kale_izena. filter(lang(?kale_izena)="eu")
  bind(iri(concat(str(wd:),?wd)) as ?honen_izena_darama)
  SERVICE <https://query.wikidata.org/sparql> {
           select distinct ?honen_izena_darama ?honen_izena_daramaLabel ?klase ?klaseLabel
           where { ?honen_izena_darama wdt:P31 ?klase. ?klase rdfs:label ?klaseLabel. filter(lang(?klaseLabel)="eu") 
                   ?honen_izena_darama rdfs:label ?honen_izena_daramaLabel. filter(lang(?honen_izena_daramaLabel)="eu")}
           group by ?honen_izena_darama ?honen_izena_daramaLabel ?klase ?klaseLabel }
  
  } group by ?klase ?klaseLabel ?zenbat order by desc(?zenbat)

Try it!

Genero-banaketa (Gasteizko kaleei izena ematen dieten gizakiak)

#Title: Zeinen izena darama? Gasteizko kaleei izena ematen dieten pertsonen generoa
#defaultView:BubbleChart
PREFIX izwb: <https://izendegi.wikibase.cloud/entity/>
PREFIX izdp: <https://izendegi.wikibase.cloud/prop/direct/>
select distinct ?genero ?generoLabel (count(?honen_izena_darama) as ?zenbat) where {
  ?kalea izdp:P3 izwb:Q3;
         izdp:P6 ?wd;
         rdfs:label ?kale_izena. filter(lang(?kale_izena)="eu")
  bind(iri(concat(str(wd:),?wd)) as ?honen_izena_darama)
  SERVICE <https://query.wikidata.org/sparql> {
           select ?honen_izena_darama ?honen_izena_daramaLabel ?genero ?generoLabel
           where { ?honen_izena_darama wdt:P31 wd:Q5; wdt:P21 ?genero. ?genero rdfs:label ?generoLabel. filter(lang(?generoLabel)="eu")
                   ?honen_izena_darama rdfs:label ?honen_izena_daramaLabel. filter(lang(?honen_izena_daramaLabel)="eu")}
            }
  
  } group by ?genero ?generoLabel ?zenbat order by desc(?zenbat)

Try it!

Lanbideen banaketa (Gasteizko kaleei izena ematen dieten gizakiak)

#Title: Zeinen izena darama? Gasteizko kaleei izena ematen dieten pertsonen lanbidea
#defaultView:BubbleChart
PREFIX izwb: <https://izendegi.wikibase.cloud/entity/>
PREFIX izdp: <https://izendegi.wikibase.cloud/prop/direct/>
select distinct ?lanbide ?lanbideLabel (count(?honen_izena_darama) as ?zenbat) where {
  ?kalea izdp:P3 izwb:Q3;
         izdp:P6 ?wd;
         rdfs:label ?kale_izena. filter(lang(?kale_izena)="eu")
  bind(iri(concat(str(wd:),?wd)) as ?honen_izena_darama)
  SERVICE <https://query.wikidata.org/sparql> {
           select ?honen_izena_darama ?honen_izena_daramaLabel ?lanbide ?lanbideLabel
           where { ?honen_izena_darama wdt:P31 wd:Q5; wdt:P106 ?lanbide. ?lanbide rdfs:label ?lanbideLabel. filter(lang(?lanbideLabel)="eu")
                   ?honen_izena_darama rdfs:label ?honen_izena_daramaLabel. filter(lang(?honen_izena_daramaLabel)="eu")}
            }
  
  } group by ?lanbide ?lanbideLabel ?zenbat order by desc(?zenbat)

Try it!

Gasteizko kaleei izena ematen dieten militarrak

#Title: Zeinen izena darama? Gasteizko kaleei izena ematen dieten militarrak

PREFIX izwb: <https://izendegi.wikibase.cloud/entity/>
PREFIX izdp: <https://izendegi.wikibase.cloud/prop/direct/>
select distinct ?honen_izena_darama ?honen_izena_daramaLabel ?jaioleku ?armada ?gerrak where {
  ?kalea izdp:P3 izwb:Q3;
         izdp:P6 ?wd;
         rdfs:label ?kale_izena. filter(lang(?kale_izena)="eu")
  bind(iri(concat(str(wd:),?wd)) as ?honen_izena_darama)
  SERVICE <https://query.wikidata.org/sparql> {
           select ?honen_izena_darama ?honen_izena_daramaLabel ?jaioleku ?armada (group_concat(?gerra;SEPARATOR=", ") as ?gerrak)
           where { ?honen_izena_darama wdt:P31 wd:Q5; wdt:P106 wd:Q47064. # militar
                  optional {?honen_izena_darama wdt:P19 [rdfs:label ?jaioleku]. filter(lang(?jaioleku)="eu").}
                  optional {?honen_izena_darama wdt:P607 [rdfs:label ?gerra]. filter(lang(?gerra)="eu").}
                  optional {?honen_izena_darama wdt:P241 [rdfs:label ?armada]. filter(lang(?armada)="eu").}
                   ?honen_izena_darama rdfs:label ?honen_izena_daramaLabel. filter(lang(?honen_izena_daramaLabel)="eu")
            } group by ?honen_izena_darama ?honen_izena_daramaLabel ?jaioleku ?armada ?gerrak
       }
  }

Try it!


Alderdi politikoen banaketa (Gasteizko kaleei izena ematen dieten gizakiak)

#Title: Zeinen izena darama? Gasteizko kaleei izena ematen dieten pertsonen alderdia
#defaultView:BarChart
PREFIX izwb: <https://izendegi.wikibase.cloud/entity/>
PREFIX izdp: <https://izendegi.wikibase.cloud/prop/direct/>
select distinct ?alderdi ?alderdiLabel (count(?honen_izena_darama) as ?zenbat) where {
  ?kalea izdp:P3 izwb:Q3;
         izdp:P6 ?wd;
         rdfs:label ?kale_izena. filter(lang(?kale_izena)="eu")
  bind(iri(concat(str(wd:),?wd)) as ?honen_izena_darama)
  SERVICE <https://query.wikidata.org/sparql> {
           select ?honen_izena_darama ?honen_izena_daramaLabel ?alderdi ?alderdiLabel
           where { ?honen_izena_darama wdt:P31 wd:Q5; wdt:P102 ?alderdi. ?alderdi rdfs:label ?alderdiLabel. filter(lang(?alderdiLabel)="eu")
                   ?honen_izena_darama rdfs:label ?honen_izena_daramaLabel. filter(lang(?honen_izena_daramaLabel)="eu")}
            }
  
  } group by ?alderdi ?alderdiLabel ?zenbat order by desc(?zenbat)

Try it!


Jaiolekuak (Gasteizko kaleei izena ematen dieten gizakiak)

#Title: Zeinen izena darama? Gasteizko kaleei izena ematen dieten pertsonen jaiolekuak
#defaultView:Map
PREFIX izwb: <https://izendegi.wikibase.cloud/entity/>
PREFIX izdp: <https://izendegi.wikibase.cloud/prop/direct/>
select distinct ?kale_izena ?honen_izena_darama ?honen_izena_daramaLabel ?jaio_gps where {
  ?kalea izdp:P3 izwb:Q3;
         izdp:P6 ?wd;
         rdfs:label ?kale_izena. filter(lang(?kale_izena)="eu")
  bind(iri(concat(str(wd:),?wd)) as ?honen_izena_darama)
  SERVICE <https://query.wikidata.org/sparql> {
           select ?honen_izena_darama ?honen_izena_daramaLabel ?jaio_gps
           where { ?honen_izena_darama wdt:P31 wd:Q5; wdt:P19 [wdt:P625 ?jaio_gps].
                   ?honen_izena_darama rdfs:label ?honen_izena_daramaLabel. filter(lang(?honen_izena_daramaLabel)="eu")}
            }
  }

Try it!

Retrieved from "https://izendegi.wikibase.cloud/w/index.php?title=Main_Page&oldid=2287"